grace/dots

dotfiles/nix configs

git clone https://git.gae.moe/grace/dots

Grace Yoderflake rewrite + a bunch\ni keep holding onto changes forever this is not how you use vcs08de973

main
6.1 KiB217 linesraw
1{
2  config,
3  host,
4  pkgs,
5  ...
6}:
7
8let
9  media = "/mnt/data/share/media";
10  music = "/mnt/data/share/music";
11  mediaUid = config.users.users.${host.user}.uid;
12  exitNode = "100.104.110.13";
13  gateway = "192.168.83.1";
14  guest = "192.168.83.2";
15  state = "/var/lib/seedbox";
16in
17{
18  services.resolved.enable = true;
19  networking.networkmanager.unmanaged = [ "interface-name:ve-seedbox" ];
20  networking.nat = {
21    enable = true;
22    internalInterfaces = [ "ve-seedbox" ];
23  };
24
25  systemd.sockets.seedbox-ssh-proxy = {
26    wantedBy = [ "sockets.target" ];
27    listenStreams = [ "127.0.0.1:2223" ];
28  };
29  systemd.services.seedbox-ssh-proxy = {
30    description = "Local SSH access to the seedbox";
31    requires = [ "seedbox-ssh-proxy.socket" ];
32    after = [ "container@seedbox.service" ];
33    serviceConfig = {
34      ExecStart = "${pkgs.systemd}/lib/systemd/systemd-socket-proxyd ${guest}:22";
35      DynamicUser = true;
36    };
37  };
38
39  systemd.tmpfiles.rules = [
40    "d ${media} 2770 ${host.user} share -"
41    "d ${music} 2770 ${host.user} share -"
42    "d ${state} 0755 root root -"
43  ];
44
45  systemd.services."container@seedbox" = {
46    unitConfig.RequiresMountsFor = [
47      media
48      music
49      state
50    ];
51  };
52
53  containers.seedbox = {
54    autoStart = true;
55    privateNetwork = true;
56    hostAddress = gateway;
57    localAddress = guest;
58    enableTun = true;
59    bindMounts = {
60      "${media}" = {
61        hostPath = media;
62        isReadOnly = false;
63      };
64      "${music}" = {
65        hostPath = music;
66        isReadOnly = false;
67      };
68      "/var/lib" = {
69        hostPath = state;
70        isReadOnly = false;
71      };
72    };
73    config =
74      {
75        config,
76        lib,
77        pkgs,
78        ...
79      }:
80      {
81        networking.hostName = "seedbox";
82        networking.useDHCP = false;
83        networking.nameservers = [ "9.9.9.9" ];
84        services.resolved.enable = false;
85        services.nscd.enable = false;
86        system.nssModules = lib.mkForce [ ];
87        system.nssDatabases.hosts = lib.mkForce [
88          "files"
89          "dns"
90        ];
91        networking.useNetworkd = true;
92        systemd.network.wait-online.enable = false;
93        systemd.network.networks."20-uplink" = {
94          matchConfig.Name = "eth0";
95          address = [ "${guest}/30" ];
96          networkConfig = {
97            Gateway = gateway;
98            LinkLocalAddressing = "no";
99            IPv6AcceptRA = false;
100          };
101          # Keep recovery SSH working without enabling general LAN access.
102          routingPolicyRules = [
103            {
104              To = "${gateway}/32";
105              Table = "main";
106              Priority = 2500;
107            }
108          ];
109        };
110
111        services.tailscale = {
112          enable = true;
113          extraSetFlags = [ "--accept-dns=false" ];
114        };
115        environment.etc."tailscale/syspolicy.json".text = builtins.toJSON {
116          ExitNodeIP = exitNode;
117          "ExitNode.AllowOverride" = false;
118          ExitNodeAllowLANAccess = "never";
119          UseTailscaleDNSSettings = "never";
120          UseTailscaleSubnets = "never";
121        };
122        services.openssh = {
123          enable = true;
124          settings.PasswordAuthentication = false;
125          hostKeys = [
126            {
127              path = "/var/lib/ssh/ssh_host_ed25519_key";
128              type = "ed25519";
129            }
130          ];
131        };
132        users.users.root.openssh.authorizedKeys.keys = import ../ssh-keys.nix {
133          host = host // {
134            name = "seedbox";
135          };
136        };
137
138        users.users.transmission = {
139          uid = lib.mkForce mediaUid;
140          isSystemUser = true;
141        };
142        services.transmission = {
143          enable = true;
144          package = pkgs.transmission_4;
145          openFirewall = false;
146          openRPCPort = false;
147          downloadDirPermissions = null;
148          settings = {
149            download-dir = media;
150            incomplete-dir = "${media}/.incomplete";
151            incomplete-dir-enabled = true;
152            umask = "007";
153            rpc-bind-address = "0.0.0.0";
154            rpc-authentication-required = false;
155            rpc-whitelist-enabled = false;
156            rpc-host-whitelist-enabled = false;
157            port-forwarding-enabled = false;
158          };
159        };
160
161        systemd.tmpfiles.rules = [
162          "d ${media}/.incomplete 0700 transmission transmission -"
163        ];
164        systemd.services.transmission-setup.unitConfig.RequiresMountsFor = [ media ];
165
166        networking.firewall.interfaces.tailscale0.allowedTCPPorts = [
167          9091
168          51413
169        ];
170        networking.firewall.interfaces.tailscale0.allowedUDPPorts = [ 51413 ];
171        networking.nftables = {
172          enable = true;
173          tables.seedbox = {
174            family = "inet";
175            content = ''
176              chain output {
177                type filter hook output priority -10; policy accept;
178                meta skuid ${toString config.users.users.transmission.uid} oifname != "tailscale0" oifname != "lo" counter drop
179              }
180            '';
181          };
182        };
183        systemd.services.transmission = {
184          requires = [ "nftables.service" ];
185          after = [
186            "nftables.service"
187            "tailscaled.service"
188          ];
189          unitConfig.RequiresMountsFor = [
190            media
191            music
192          ];
193          preStart = ''
194            ${pkgs.coreutils}/bin/timeout 10 ${pkgs.tailscale}/bin/tailscale status --json |
195              ${pkgs.jq}/bin/jq -e --arg ip ${lib.escapeShellArg exitNode} '
196                . as $status |
197                .BackendState == "Running" and
198                .ExitNodeStatus.Online == true and
199                any(.Peer[]?;
200                  .ID == $status.ExitNodeStatus.ID and
201                  (.TailscaleIPs | index($ip)) != null
202                )
203              ' >/dev/null
204          '';
205          serviceConfig = {
206            BindPaths = [ music ];
207            # Hide nspawn's read-only /run/host so systemd can stage the sandbox's os-release.
208            TemporaryFileSystem = [ "/run/host" ];
209            Restart = "on-failure";
210            RestartSec = "10s";
211          };
212        };
213
214        system.stateVersion = "26.05";
215      };
216  };
217}